小女孩张芸京:用excel制作现金与银行日记帐

利用excel的统计和计算功能，可以制作一个记帐的表格，只要逐笔输入记录，就可自动显示结果。

下面以现金与银行帐页为例介绍制作方法。
通常企业会有一个现金帐户和多个银行帐户。现在假设有一个现金帐和三个银行帐户，我们可设置六个工作表。

每个表的作用：
首页：显示现金与银行的汇总统计表
列表：设置需要在帐簿中显示的对方科目与用款部门
现金：现金帐页
银行1：第一个银行帐户
银行2：第二个银行帐户
银行3：第三个银行帐户

先制作“列表”工作表，如下图：

为了在后面的工作表中使用下拉框输入这些项目，需要定义两个“名称” 
在A列输入“对方科目”，这个需要在现金日记帐中使用；在C列输入“部门”，这个在现金和银行帐页都会用到。 
按图中所示，选中A1:A10区域，按上面菜单栏“插入－名称－定义”，调出“定义名称”对话框。 

 
在“当前工作簿中的名称”框中输入“对方科目”，在下面“引用位置”框中输入“=列表!$A$1:$A$10”，最后按“确定”就行了。 
这样“对方科目”名称就定义好了，按这个方法选中C1:C10区域，再定义一个“部门”名称。 
提示：如果只是简单的登记，不想汇总各科目或各部门的支出，可省略“列表”的制作。 

制作现金帐页 

有公式的单元格如下： 

C2单元格，公式 =COUNTA(C4:C1000) 
 用于统计记录的行数

G2单元格，公式 =SUBTOTAL(9,G4:G1000) 
 用于统计借方发生额，之所以用SUBTOTAL函数是为了方便使用“自动筛选”时，可只汇总显示出来的数据，不会汇总筛选时隐藏的数据。

H2单元格，公式 =SUBTOTAL(9,H4:H1000) 
 用于统计贷方发生额，与G2格中的公式类似。

J2单元格，公式 =ROUND(J1+G2-H2,2) 
 用于计算期末余额，它使用了ROUND函数对结果进行四舍五入保留两位小数。

J4单元格，公式 =ROUND(J1+G4-H4,2) 
 用于计算第一笔业务录入数据后的余额

J5单元格，公式 =ROUND(IF(A5="",0,J4+G5-H5),2) 
 用计计算第二笔及以下业务录入后的余额，使用了IF判断函数，当同一行的日期（A列）单元格未填写时，只显示一个0值（可将G\H\J列的单元格格式设置为“会计专用”，这样当数值为0时，只显示一个短横线）。

 要选中J5单元格，用拖动复制的方法向J列下面填充复制公式。

提示：如果A列中的日期格式不是你想要的，可选中A列，按上面菜单“格式－设置单元格格式”，在弹出窗口中选“数字”选项卡，从左侧找到“日期”，然后从右侧就可以设置想要的日期格式了。 

添加“部门”下拉框： 

选中E列，按上面菜单“数据－有效性”，在弹出的“有效性窗口”中选“设置”选项卡，从“允许”中选择“序列”，在“来源”中输入如图中的公式“=部门”（注意：等号要在英文状态下输入） 

添加“对方科目”下拉框： 
选中F列，按上面方法设置，不同的是在“来源”框中输入公式“=对方科目” 

制作银行帐页 
其实银行帐页的格式与现金帐页基本相同，所不同的只是将F列改成了“支票号码”，表格中的公式完全一样。 
提示：可在制作好“现金”帐页后，按CTRL+A将其“全选”，按“复制”，到银行表中选中A1单元格，“粘贴”就行了，这样可提高制作的速度。 

帐页制作好后就能录入数据了，先在现金与银行帐页的J1单元格输入“期初余额”，然后从第三行开始逐笔输入数据就行了，J列的公式如果不够用，可由J5单元格向下拖动复制。 

最后制作首页中的汇总表格 

 
“汇总表”公式可按下图输入 

 

“部门用款明细表”公式如下： 
H4单元格公式 =列表!C2 
 将此公式拖动复制到H13单元格。
I4单元格公式 =SUMIF(现金!$E$4:$E$1000,$H4,现金!$H$4:$H$1000) 
 将此公式拖动复制到I13单元格。
J4单元格公式 =SUMIF(银行1!$E$4:$E$1000,$H4,银行1!$H$4:$H$1000) 
 将此公式拖动复制到J13单元格。
K4单元格公式 =SUMIF(银行2!$E$4:$E$1000,$H4,银行2!$H$4:$H$1000) 
 将此公式拖动复制到K13单元格。
L4单元格公式 =SUMIF(银行3!$E$4:$E$1000,$H4,银行3!$H$4:$H$1000) 
 将此公式拖动复制到L13单元格。
M4单元格公式 =SUM(I4:L4) 
 将此公式拖动复制到M14单元格。
I14单元格公式 =SUM(I4:I13) 
 将此公式向右拖动复制到L14单元格。

到此，整个帐页设置完毕，只要在现金与银行帐页输入数据，就会在“首页”表中随时显示出统计数据。 
另外还可以在现金或银行帐页中，选中A3:J3后，按菜单上的“数据－筛选－自动筛选”，当出现筛选按钮后，可对当前帐页上的所需数据进行筛选统计。 

下图是在“现金”帐页中输入数据的一个例子