男人心脏的位置图:各类指标原代码公式及解释-爱钱钱爱我 博弈股手．-zhou1381-金融界博客

各类指标原代码公式及解释
(2009-06-19 12:50:03)
主　　题： 曾超公式
◆
技术指标公式：MOON（跟庄到顶）主图
Var1:=(LOW+HIGH+CLOSE)/3;
操作: MA(Var1,5),linethick2;
拉升:HHV(操作,13),colorred,linethick2;
压力:HHV(操作,60),colorred;
买卖:LLV(操作,13),linethick2;
底部支撑: LLV(LOW,60)*1.02;
顶部: HHV(HIGH,60)*0.98,COLORred;
STICKLINE(操作>ref(操作,1),操作,操作+0.018,5,0),coloryellow,linethick2;
STICKLINE(拉升>ref(拉升,1),拉升,拉升+0.018,5,0),coloryellow,linethick2;
STICKLINE(拉升< ref(拉升,1),拉升,拉升,4,1),colorcccc00;
STICKLINE(拉升=ref(拉升,1),拉升,拉升,1,1),colorred;
STICKLINE(买卖=ref(买卖,1),买卖,买卖,1,1),colorred;
STICKLINE(买卖>ref(买卖,1),买卖,买卖+0.028,4,1),colormagenta,linethick2;
STICKLINE(顶部< ref(顶部,1),顶部,顶部,1,1),colorblue;
STICKLINE(顶部=ref(顶部,1),顶部,顶部,7,1),colorcyan;
STICKLINE(买卖< ref(买卖,1),买卖,买卖,1,1),colorgreen;
STICKLINE(压力=ref(压力,1),压力,压力,7,1),colorcyan;
STICKLINE(底部支撑=ref(底部支撑,1),底部支撑,底部支撑,1,1),colorred;
STICKLINE(底部支撑< ref(底部支撑,1),底部支撑,底部支撑,1,1),colorwhite;
---------------------------------
用法：沿红色、粉红色、黄色粗线条持股；横线及线条向下，空仓。
---------------------------------
◆
技术指标公式：跟庄到顶 参数描述： N1(10,100,20)N2(20,200,60)
Var1:=(LOW+HIGH+CLOSE)/3;
CB: MA(Var1,5);
A1: HHV(CB,N1);
A2: HHV(CB,N2);
B1: LLV(CB,N1);
B2: LLV(LOW,N2)*1.02;
A3: HHV(HIGH,N2)*0.98;
---------------------------------
N，N1，N2日内的最低成本*系数C1。股价只要不再创新低(高），A1、B、A2、B1线就保持水平状态。从而形成对股价的支撑线CB、B1、B2，压力线A1、A2、A3。当股价不断上涨时，也就是说，在CB=A1，A1＝A2时，其市场含义是压力与支撑相碰撞重合(尤如正负原子碰撞，必有一个能量质变)，才能引发一波上涨行情。
显著特点:趋势性强，买入、跟庄、逃顶信号准确。
1.在股价下降通道中，一般不会发出买入信号。既使在底部发出极少数失败买入信号，也不会被深套。
2.具有极强的跟庄信号。一旦在底部买入，可按CB=A1、A1=A2一路持有，跟庄到顶。CB与A1刚重叠时，如CB线上翘有力，可介入。
3.逃顶信号及时。等到高位股价跌穿A2，或CB与A2分开朝下，必须减仓或清仓止损，逃顶。
---------------------------------
Param#1>5; Param#2>20;
---------------------------------
◆
技术指标公式：CCCB ((修正)庄家生命线)
---------------------------------
Var1:=BARSSINCE(LLV(LOW,120));
Var2:=SUM(AMOUNT*0.01,Var1)/SUM(VOL,Var1);
Var3:=SUMBARS(IF(VOL>CAPITAL*0.5,CAPITAL*0.49,VOL),CAPITAL*0.5);
Var4:=SUMBARS(IF(VOL>CAPITAL,CAPITAL*0.99,VOL),CAPITAL);
Var5:=SUMBARS(IF(VOL>CAPITAL*2,CAPITAL*1.99,VOL),CAPITAL*2);
Var6:=SUMBARS(IF(VOL>CAPITAL*4,CAPITAL*3.99,VOL),CAPITAL*4);
Var7:=MA(SUM(AMOUNT*0.01,Var3)/SUM(VOL,Var3),5);
Var8:=MA(SUM(AMOUNT*0.01,Var4)/SUM(VOL,Var4),5);
Var9:=MA(SUM(AMOUNT*0.01,Var5)/SUM(VOL,Var5),5);
VarA:=MA(SUM(AMOUNT*0.01,Var6)/SUM(VOL,Var6),5);
VarB:=IF(SUM(VOL,0)< CAPITAL*0.6,Var2,Var7);
VarC:=IF(SUM(VOL,0)< CAPITAL*1.2,Var2,Var8);
VarD:=IF(SUM(VOL,0)< CAPITAL*2.5,Var2,Var9);
VarE:=IF(SUM(VOL,0)< CAPITAL*4.8,Var2,VarA);
短线: IF(VarB=0,AMOUNT*0.01/VOL,VarB);
中线: IF(VarC=0,AMOUNT*0.01/VOL,VarC);
长线: IF(VarD=0,AMOUNT*0.01/VOL,VarD);
强支压: IF(VarE=0,AMOUNT*0.01/VOL,VarE), CIRCLEDOT;
---------------------------------
用移动均线时，一旦股价跌穿5、10均线，想在20或30日线附近低吸，就是买不到，原来在20或30日线上隐藏有庄家生命线获支撑。所以用庄家生命线买入要踏实得多，准确性高得多。只有在庄家生命线附近买进，这才是“低吸”真正含义，达到与庄共舞。
本指标另辟设计思路，在每日成交量中假设定性庄家吃仓量，测算庄家买入。低吸高抛摊薄成本，建立一个数学模型，设计不同周期庄家大致成本形成庄家生命线。短线--C1；中线--C2；长线--C3；强支撑压力线--Z4。
本指标运算较为复杂，运算速度较慢。所以股票翻页，主图放大缩小时要慢，不能过快。
实战技法:
<1>股价在下降通道中，在C1线下运行，一般不介入。除非股价严重偏离C1，用CYS<-20介入短线抢反弹，为一买入机会。
<2>股价放量上穿C1，为一买入点。如C1上穿C2，股价在底部区域，是大胆逢低介入的好机会。
<3>C1、C2、C3形成托或多头初期，只要股价偏离C2、C3不远，可逢低大胆加仓买进。
<4>如在趋势向上途中，股价在C1、C2、C3、Z4之间，狭窄空间内被夹起来，窄幅整理，价跌不去，而在庄家生命线之间或附近停留3-5天，是买入良机，很快就会有向上突破。
<6>密切关注股价偏离庄家生命线远近，配合CCCBPL指标，如股价偏离C3线+30%-50%以上，切不可追高，否则90%会被套住。在15%以下安全性较高。超出15%以上只能做短线，须设立止损位，快进快出。因为庄家一般拉离成本区30%-50%会减仓，做波段高抛低吸，逐步推高。一鼓作气拉高100%以上毕竟少数。
<7>在涨幅过大CCCBPL中的PL3>50-100以上顶部，股价跌破C1短期线，一般是第一次最好减仓、出逃机会。股价盘落跌破强支撑压力线Z4，是最后出逃机会，说明中线已走弱。
<8>股价长时间在C3、Z4之下运行，说明前期庄家已大量出货，C3、Z4反而是强压。放量突破C3、Z4后，股价才能真正走好。 ---------------------------------
◆
技术指标公式：CCCBPL (庄家获利%2)
Var1:=SUM(AMOUNT*0.01,0)/SUM(VOL,0);
Var2:=SUMBARS(IF(VOL>CAPITAL*2,CAPITAL*1.99,VOL),CAPITAL*2);
Var3:=SUMBARS(IF(VOL>CAPITAL*4,CAPITAL*3.99,VOL),CAPITAL*4);
Var4:=MA(SUM(AMOUNT*0.01,Var2)/SUM(VOL,Var2),5);
Var5:=MA(SUM(AMOUNT*0.01,Var3)/SUM(VOL,Var3),5);
Var6:=IF(SUM(VOL,0)< CAPITAL*2.5,Var1,Var4);
Var7:=IF(SUM(VOL,0)< CAPITAL*4.5,Var1,Var5);
Var8:=(CLOSE-REF(Var6,5))/REF(Var6,5)*100;
Var9:=(CLOSE-REF(Var7,5))/REF(Var7,5)*100;
庄中线获利: IF(Var8<0,0,Var8);
庄中线获利, COLORSTICK;
庄长线获利: IF(Var9<0,0,Var9);
获利盘比例除十: WINNER(CLOSE)*10;
---------------------------------
本指标为庄家生命线CCCB配套技术指标。如中期、长期庄家获利为0，表示庄家未获利，正进行震荡吸筹，或前期庄家获利已出货。结合现股价位置和阶段换手来分析判断。
结合CCCB指标，密切关注庄家获利率高低，如庄家获利率在+35%以上，切不可盲目追高，尤其是在次高位，否则90%会被套住。在20%以下安全性较高。超出20%以上只能做短线，须设立止损位，快进快出。因为庄家一般拉离庄家生命线区35%-50%会减仓，做波段高抛低吸，逐步推高。一鼓作气拉高100%以上的强庄股毕竟是少数。
---------------------------------
◆
条件选股公式：选股A (A1=A2跟庄到顶2)
Var1:=MA(CLOSE,5);
Var2:=MA((CLOSE+LOW+HIGH)/3,5);
Var3:=HHV(Var2, 20);
Var4:=HHV(Var2, 60);
Var3=Var4 AND REF(Var3,1)< Var4*0.99 AND CLOSE>REF(CLOSE,1)*1.02 AND VOL>MA(VOL,10);
---------------------------------
◆
条件选股公式：选股B (CB=A1跟庄到顶2) 参数描述： N(5,100,20)
Var1:=MA((CLOSE+LOW+HIGH)/3,5);
Var2:=HHV(Var1,N);
Var1=Var2 AND VOL>MA(VOL,10)*1.2 AND CLOSE>REF(CLOSE,1)*1.01;
---------------------------------
◆
条件选股公式：选股C (庄家生命线2) 参数描述： N1(20)N2(-10)P1(10)P2(10)
Var1:=SUMBARS(VOL,CAPITAL*0.5);
Var2:=SUMBARS(VOL,CAPITAL);
Var3:=SUMBARS(VOL,CAPITAL*2);
Var4:=MA(SUM(AMOUNT*0.01,Var1)/SUM(VOL,Var1),5);
Var5:=MA(SUM(AMOUNT*0.01,Var2)/SUM(VOL,Var2),5);
Var6:=MA(SUM(AMOUNT*0.01,Var3)/SUM(VOL,Var3),5);
Var7:=ABS((Var4-Var5)/Var5*100)< P1;
Var8:=ABS((Var5-Var6)/Var6*100)< P2;
Var9:=(CLOSE-Var6)/Var6*100;
Var4>Var5 AND Var5>Var6 AND Var9< N1 AND Var9>>N2 AND Var7 AND Var8;
---------------------------------
选庄家生命线形成多头，N1、N2为股价偏离长期庄家生命线程度。未完善，仅供试用。
主　　题： 仓位控制公式
1、资金管理是控制系统中风险和收益平衡的唯一工具，建立一个安全边际的仓位比例公式是我们必须面对的问题，一个粗陋的公式如下：
安全边际比例仓位＝（ｆ－ｓ－ｃ）/ｚ/ｗ
ｆ＝愿意为该次交易承受的最大亏损
ｓ＝在该次交易中已经发生的亏损或盈利
ｃ＝以当前市价下跌至止损位将承受的亏损
ｚ＝现价到止损价格的百分比
ｗ＝资金总额
该公式的最大优点在于能始终锁定风险，但是把风险度量为以现价到止损价格却只是个人臆断，在实际操作中可能因流动性风险而导致损失被扩大。
2、控制仓位的限额应该是这样一个公式：
最大持仓率＝总资金损失额限度/(止损位置X操作失误率)
比如，总资金控制每次损失2%，止损位置设立5%，而实际交易的失败次数大致是60%。那么最大持仓率＝2%/(5%X60%)＝66%。这样无论如何，亏损总是可以限制在一定的幅度内，在交易前就可以知道你最多会亏多少。应该是有利于大胆的买入吧。
3、用多少资金与你的评估概率有关。例如，用50%的资金，意味着你的胜算概率是70%多一点；用70%的资金则意味着85%的胜算概率。其简算公式=概率的平方值
4、Kelly公式：记赢的概率为P，赔率的B，则最优的投注比例（占总资金的比率）：
f=[(1+B)*P-1]/B
对于概率、赔率已知的单一、可连续下注的赌局，这是4个公式中唯一一个严格、科学的公式。
主　　题： 特色公式
◆
DY-神秘波段1
DY1:=(2*CLOSE+HIGH+LOW)/4;
DY2:=LLV(LOW,34);
DY3:=HHV(HIGH,34);
低位区:20,colorBLUE;
高位区:80,color999900;
DYA:EMA((DY1-DY2)/(DY3-DY2)*100,30),color33CCFF;
DYB:EMA(DYA,5),colorFFFFFF;
A1:=EMA((DY1-DY2)/(DY3-DY2)*100,9);
B1:EMA((0.667*REF(A1,1)+0.333*A1),2),COLORGREEN;
Var1:IF(A1>=B1,A1,B1),COLORRED;
Var2:IF(B1-A1,B1,A1),COLORGREEN;
买入:IF(CROSS(B1 ,20),30,0),colorred;
[讨论]
1、神秘波段进入白色底线之下，此时辅助判市金叉翻红，买入。神秘波段不在白线之下时，辅助判市翻红不算；神秘波段在白线之下，辅助判市不翻红也不急着买。
2、神秘波段进入红色顶线之上，此时辅助判市死叉翻绿，卖出。只要神秘波段在白线之上时，辅助判市死叉翻绿即可卖出，如果大盘仍是买入信号此时可换股操作，好股多的是，安全第一。
3、只有在大盘的辅助判市底部翻红情况下才可满仓操作，如果大盘的辅助判市翻绿，仓位坚决不能超过1/3。
只要严格按照以上三条操作，年收益率最少肯定在50%以上。系列指标共六个：DY-多空博弈，DY-辅助成交量，DY-辅助判市，DY-双趋势指标，DY-通道指标，DY-神秘波段。分析家的各种波段都比它好得多，大概不是正版的。
◆
DY-神秘波段2
KAV:=(2*CLOSE+HIGH+LOW)/4;
AK:=EMA((KAV-LLV(LOW,34))/(HHV(HIGH,34)-LLV(LOW,34))*100,34);
DD:=EMA(0.667*REF(AK,1)+0.333*AK,5);
MK:=EMA((KAV-LLV(LOW,34))/(HHV(HIGH,34)-LLV(LOW,34))*100,5);
NK:=EMA(Mk,5);
NK,COLORGREEN;
DD,COLORWHITE;
AK,COLORYELLOW;
STICKLINE(MK>NK,MK,NK,5,0),COLORRED;
STICKLINE(MK<=NK,MK,NK,5,0),COLORGREEN;
13;
35;
79;
◆
DY-多空博弈
SSL:=EMA(C,3);
SSL,COLORGREEN;
MM:EMA((SLOPE(C,22)*20+C),55),COLORWHITE;
STICKLINE(SSL>MM,SSL,MM,1,0),COLORMAGENTA;
STICKLINE(SSL<=MM,SSL,MM,1,0),COLORGREEN;
STICKLINE(C>=O,C,O,8,0),COLORRED;
STICKLINE(C>=O,H,L,0,0),COLORRED;
STICKLINE(C<=O,C,O,8,0),COLORGREEN;
STICKLINE(C<=O,H,L,0,0),COLORGREEN;
◆
DY-辅成交量
MID:=(HIGH+LOW+CLOSE)/3;
CR26:=SUM(MAX(0,HIGH-REF(MID,1)),26)/SUM(MAX(0,REF(MID,1)-L),26)*100;
CHIU:=SMA(CR26,25,1);
CHIU1:=EMA(CR26,5);
CHIU2:=EMA(CR26,10);
CHIU1,COLORRED;
CHIU,COLORYELLOW;
CHIU2,COLORWHITE;
STICKLINE(CHIU1>0,CHIU1,0,5,0),COLORRED;
◆
DY-辅助判市
B53:=(MA(CLOSE,9)-REF(MA(CLOSE,9),1))/REF(MA(CLOSE,9),1)*100;
JX:=ATAN(B53)/3.1416*180;
DYSMK1:=SMA(JX,10,1);
DYSMD1:=SMA(DYSMK1,5,1);
DYSMD:DYSMD1,COLORGREEN;
DYSMK:DYSMK1,COLORYELLOW;
STICKLINE(DYSMK>DYSMD,DYSMK,DYSMD,2,0),COLORRED;
STICKLINE(DYSMK<=DYSMD,DYSMK,DYSMD,2,0),COLORGREEN;
20;
-20;
◆
D底部出现
Var1:=MA(CLOSE,104);
Var2:=Var1-2*STD(CLOSE,104);
X: CLOSE-(CLOSE-Var2)/Var2*200-CLOSE/2.618, COLORSTICK;
X1: X;
◆
costbias(成本乖离率) 参数描述：d1(1,35,20) d2(1,35,1)
volume:=vol*100;
namount1:=sum(amount,d1);
namount2:=sum(amount,d2);
nvolume1:=sum(volume,d1);
nvolume2:=sum(volume,d2);
avgcost1:=namount1/nvolume1;
avgcost2:=namount2/nvolume2;
costbias:(avgcost1-avgcost2)/avgcost2;
用法: costbias<-0.1时买入；三天内回落5%卖出。
◆
沧海龙吟
龙: WINNER(CLOSE)-COST(50)/CLOSE;
海: -1.5, POINTDOT;0;-1;-2;
本指标揭示了一个简单的市场事实：获利盘与股价中心的位置关系。在弱势市场中和超跌状态下能够获利的一定是一部分先知先觉的人。而本指标就是捕捉这一部分先知先觉人行为的指标。
用法：
（1）在大盘环境恶劣的情况下，当龙线运行到-2时抄底有96％的成功率。
（2）在大盘环境较好的情况下，本指标是一个很好的波段炒作指标，当龙线运行到-1以下时都是很好的介入时机，一般有85％以上的成功率，龙线运行到0以上时，一般短线都将见顶，疯牛除外。
◆
阿Z五分钟起爆（只用于5分钟K线）N(100,500,250)
MA5:=MA(CLOSE,5);MA10:=MA(CLOSE,10);MA20:=MA(CLOSE,20);
KL:=LLV(L,5)=LLV(L,N);
HE:=(CLOSE>OPEN OR CLOSE>REF(CLOSE,1)) AND VOL>REF(VOL,1);
KLA:=KL AND COUNT(HE,3)>=2;
JCC:=COUNT(CROSS(MA5,MA10),3)=1 AND COUNT(CROSS(MA10,MA20),3)=1;
HAA:=KLA AND JCC AND COUNT(KLA AND JCC,30)>=1;
阿Z起爆5分:IF(HAA AND COUNT(HAA,10)>=1,11,0),COLORRED;
◆
长线
VAR1:=REF(CLOSE,1);
VAR2:=SUM(VOL,2)/((HHV(HIGH,2)-LLV(LOW,2))*100);
VAR3:=(CLOSE-VAR1)*VAR2;
VAR4:=SUM(VAR3,0);
VAR5:=SMA(VAR4,10,1);
VAR6:=SMA(VAR4,20,1);
LON: VAR5-VAR6;
LONMA: MA(LON,10);
主　　题： 多空指数
◆
多头:ESTDATA(1),linethick0;
空头:ESTDATA(2),linethick0;
AI:(ESTDATA(3)/ESTDATA(4))/(ESTDATA(5)/ESTDATA(6)),LINETHICK0;
升量:ESTDATA(5),linethick0;
跌量:ESTDATA(6),linethick0;
升家:ESTDATA(3),linethick0;
跌家:ESTDATA(4),linethick0;
STICKLINE(ESTDATA(1)>=0,0,ESTDATA(1),8,1),colorred;
STICKLINE(REVERSE(ESTDATA(2))<=0,0,REVERSE(ESTDATA(2)),8,1),colorgreen
◆
多头排列 ESTDATA(1)
Var1:=MA(C,5)>MA(C,10) AND MA(C,10)>MA(C,20) AND MA(C,20)>MA(C,30);
多头排列:SUM(IF(Var1,1,0),1)
空头排列 ESTDATA(2)
Var1:=MA(C,5)< MA(C,10) AND MA(C,10)< MA(C,20) AND MA(C,20)< MA(C,30);
空头排列:SUM(IF(Var1,1,0),1)
上升家数 ESTDATA(3)
Var1:=IF(C>REF(C,1),1,0);
上升家数:SUM(Var1,1)
下跌家数 ESTDATA(4)
Var1:=IF(C< REF(C,1),1,0);
下跌家数:SUM(Var1,1)
上升股量 ESTDATA(5)
Var1:=IF(C>REF(C,1),V,0);
上升股量:SUM(Var1,1)
下跌股量 ESTDATA(6)
Var1:=IF(C< REF(C,1),V,0);
下跌股量:SUM(Var1,1)
◆
公式中的AI即是阿姆斯指数，发明人是美国的小理查德·阿姆斯，计算方法及用法见于其所著的《股市无敌》一书，现根据该书简介用法如下：
AI测量的是市场的内在活力，它确定成交量的走向和变动的难易程度。作为在一个交易日期间或之后的计算结果，它表明了上升的股票是否得到了它们应得的交易量份额，和其得到或未得到交易量份额的程度。
1、AI等于1，表示目前是均衡状态，即上涨股票成交量与下跌股票成交量之比等于上升股数与下跌股数之比；
2、AI大于1，表示目前是弱势（熊市）状态，即上涨股票成交量与下跌股票成交量之比小于上升股数与下跌股数之比；
3、AI小于1，表示目前是强势（牛市）状态，即上涨股票成交量与下跌股票成交量之比大于上升股数与下跌股数之比；
4、假如数值70%的时间落在0.75和1.15之间，那么可以认为处于正常状态。当数值突然脱离这一正常范围，就值得密切注意了，特别是当它与同期的价位移动方式相对比的情况下更是这样。能看到比值小于0.5或大于1.75的机会是极少的，一旦出现必将引起投资者激烈的情绪反应。
总之，越低的数值表示越好的状态。因为它们显示了比上升股票数目相对应的还要多的上升股票交易量；而高的阿姆斯数值表明下跌的股票占据了优势，因而被认为是坏的或熊市的征兆。
注意：阿姆斯指数不见得完全适用于中国的证券市场，不应盲目照搬。如“能看到比值小于0.5或大于1.75的机会是极少的”，在上证指数上能看到的那就太多了。
公式中的多头和空头指的是：当日交易的多头排列的家数和空头排列的家数。这样计算是不科学的，但比较直观。科学一点的应是多头排列的家数和空头排列的家数分别占A股总家数或当日交易的A股总家数的百分比，这样可以避免因新股不断上市所造成的数值偏差过大。
用法：注意观察指数历史上高低点的空头与多头的数值，例如，跌势中，空头800，多头10，说明可能到底；升势中，空头10，多头600，说明可能到顶。当然还应根据其他指标一起研判。注意多空背离现象。
◆
请先引入上面的七个公式，然后按下列顺序建横向统计函数：
多头排列:ESTDATA(1);
空头排列:ESTDATA(2);
上升股数:ESTDATA(3);
下跌股数:ESTDATA(4);
上升股量:ESTDATA(5);
下跌股量:ESTDATA(6);
步骤是一样的，现以多头排列为例，其他依次仿建即可，注意不要颠倒序号：选择横向统计管理；按新增；选择计算公式栏中的“多头排列”公式，在数据名称栏中添入：多头排列，计算周期即日线，指标线为多头排列，横向统计方法为全部累加，其他就不用设置了，用系统默认即可，点击设置范围按钮，选中A股板块，按选择范围的确定按钮；按确定按钮，到此即完成了多头排列横向统计函数的设置，其他的可依序按上述方法建立；六个横向统计函数全部建完后，按全部刷新按钮，刷新后选择关闭，至此全部完成，公式已可显示；每天收盘时，先选中更新当日扩展、横向统计数据，然后再执行收盘作业。
主　　题： 趋势跟踪公式
技术指标公式：TCF 参数描述：N(1,35,3)
ZCHANGE:=IF(C>REF(C,1),C-REF(C,1),0);
FCHANGE:=IF(C< REF(C,1),C-REF(C,1),0);
ZCF:=IF(C>REF(C,1),ZCHANGE+REF(ZCHANGE,1),0);
FCF:=IF(C< REF(C,1),FCHANGE+REF(FCHANGE,1),0);
ZTCF:SUM(ZCHANGE,N)-SUM(FCF,N)*(-1);
FTCF:SUM(FCHANGE,N)*(-1)-SUM(ZCF,N);
ZTCF与FTCF的正值，是衡量目前趋势的强度。每日的ZTCF与FTCF的值不可能皆为正，因为不可能同时存在向上与向下的趋势，但有可能同时为负，此时为盘整。因此：
若ZTCF>0且FTCF<0，则进场作多；
若ZTCF<0且FTCF>0，则进场作空；
若ZTCF<0且FTCF<0，不改变之前的操作策略。
以完全机械式的交易，不掺杂个人的主观判断，TCF可带来惊人的获利表现。
如果再加入停损机制的话，将会减少损失，进而增加净利，其获利将大大提升。
此外，还可以再加强资金的控管，如加码等，将使TCF效能发挥到极至。
参数的设定：原作者以35天进行测试，3天是适于台指期货操作的参数。可根据沪深两市个股的实际情况适当调整。
主　　题： 一目均衡
◆
技术指标公式：一目均衡1
基準線:(HHV(H,26)+LLV(l,26))/2,LINETHICK2,COLORRED;
轉換線:(HHV(H,9)+LLV(L,9))/2,LINETHICK2,COLORGREEN;
DL:=(HHV(H,26)+LLV(l,26))/2;
FN:=26;
DELAYLAST:=BACKSET(ISLASTBAR,FN);
PARTLINE(NOT(DELAYLAST),DL),COLORYELLOW;
先行上限:(轉換線+基準線)/2,SHIFT26,LINETHICK0;
先行下限:(HHV(H,52)+LLV(L,52))/2,SHIFT26,LINETHICK0;
FILLRGN(先行上限>先行下限,先行上限,先行下限),SHIFT26,COLORMAGENTA;
FILLRGN(先行下限>先行上限,先行上限,先行下限),SHIFT26,COLORCYAN;
◆
技术指标公式：一目均衡2
基准线:(HHV(H,26)+LLV(l,26))/2,LINETHICK2,COLORRED;
转换线:(HHV(H,9)+LLV(L,9))/2,LINETHICK2,COLORGREEN;
Var1:=(转换线+基准线)/2;
Var2:=(HHV(H,52)+LLV(L,52))/2;
先行上限:REF(Var1,26);
先行下限:REF(Var2,26);
STICKLINE(先行上限>先行下限,先行上限,先行下限,0.8,1),COLORMAGENTA;
STICKLINE(先行上限<先行下限,先行上限,先行下限,0.8,1),COLORCYAN;
◆
用法(根据有关资料汇总):
1、若"延迟线"在收盘价价线之上，表示现在股价正处于涨势，反之则是跌势。注意，这一条有点不合逻辑，如"延迟线"是当天收盘价显示在26天之前，那就不存在之上之下，只存在持平。
2、"转换线"和"基准线"的应用可视为两条移动平均线(短天期的为"转换线"，长天期的为"基准线")，配合葛兰碧八大法则来决定买卖点。
3、在"先行上限"和"先行下限"所交插包围出的区域涂上颜色，此区域叫做"云雾区"。一目均衡最重要的就是"云雾区"的用法，"云雾区"可视为支撑或压力区，若所有的线型("转换线"，"基准线"和"收盘价线")都向上穿越它，则可谓涨势确立，反之若向下穿越，则跌势确立。因此聪明的投资朋友可以把它当做支撑或压力来应用。
4、原创者的参数52、26、9分别代表2个月、1个月、1周半，当时日本一周交易6天，所以使用上述的参数，现在应该改成44、22、8可能较为恰当。
5、将高低点的观念应用上来，颇符合市场的实况描述，因为高点与低点之所以为高低点，有一定的价值意义。
6、让交易人能一眼看出目前的趋势，此指针主要的功能是作趋势观察而用。
7、若价格落入"云雾区"，代表无方向性，多空方均应小心应付。
指标缺点：当盘整时本指标无法有效表达，需配合其它振荡指针使用。如RSI、KD等。
指标适用商品：所有股票指数。如加权台指、摩根台指、日经、纳斯达克、道琼指数等。
主　　题： 迪马克三公式
TD-DMKI 参数描述： N(1,100,13)
DMH:=SUM(IF(H>REF(H,1),H-REF(H,1),0),N);
DML:=SUM(IF(L>REF(L,1),0,REF(L,1)-L),N);
DMKI:DMH/(DMH+DML);
0.75;
0.5;
0.25;
TD-DMKII 参数描述： N(1,100,8)
DMKH:=SUM(IF(H-REF(C,1)>0,(H-REF(C,1))+(C-L),C-L),N);
DMKM:=SUM(IF(REF(C,1)-L>0,(REF(C,1)-L)+(H-C),H-C),N);
DMKII:DMKH/(DMKH+DMKM);
0.6;
0.5;
0.4;
TD-REI 参数描述： N(1,100,8)
DIF1:=H-REF(H,2);
DIF2:=L-REF(L,2);
NUM1:=IF(REF(H,2)< REF(C,7) AND REF(H,2)< REF(C,8) AND H< REF(L,5) AND H< REF(L,6), 0,1);
NUM2:=IF(REF(L,2)>REF(C,7) AND REF(L,2)>REF(C,8) AND L>REF(H,5) AND L>REF(H,6), 0,1);
REI1:=(DIF1+DIF2)*NUM1*NUM2;
REI2:=ABS(DIF1)+ABS(DIF2);
REI:SUM(REI1,N)/SUM(REI2,N);
0.4;
0;
-0.4;
主　　题： 小天K-KDJ
◆
技术指标公式：KDJXT小天 (小天K-KDJ) 参数描述： NN(1,111,20)
STICKLINE(C>=O,C,O,7,0),COLORRED;
STICKLINE(C>=O,C,O,4,0),COLORRED;
STICKLINE(C>=O,C,O,2,0),COLORRED;
STICKLINE(C>=O,H,L,0,0),COLORRED;
STICKLINE(C<=O,C,O,7,0),COLORGREEN;
STICKLINE(C<=O,C,O,4,0),COLORGREEN;
STICKLINE(C<=O,C,O,2,0),COLORGREEN;
STICKLINE(C<=O,H,L,0,0),COLORGREEN;
RSV:=(CLOSE-LLV(LOW,13))/(HHV(HIGH,13)-LLV(LOW,13))*100;
K:=SMA(RSV,3,1);
D:=SMA(K,3,1);
J:=3*K-2*D;
RSV12:=(CLOSE-LLV(LOW,34))/(HHV(HIGH,34)-LLV(LOW,34))*100;
K12:=SMA(RSV12,3,1);
D12:=SMA(K12,3,1);
J12:=3*K12-2*D12;
RSV24:=(CLOSE-LLV(LOW,55))/(HHV(HIGH,55)-LLV(LOW,55))*100;
K24:=SMA(RSV24,3,1);
D24:=SMA(K24,3,1);
J24:=3*K24-2*D24;
支撑位:IF(CROSS(J,J24),L,REF(L,BARSLAST(CROSS(J,J24)))),COLORYELLOW,LINETHICK2;
压力位:IF(CROSS(J24,J),H,REF(H,BARSLAST(CROSS(J24,J)))),COLORRED,LINETHICK2;
U2L:=IF(C>=MA(C,NN),80,50);
L2L:=IF(C>=MA(C,NN),50,20);
RH1:=IF(J< U2L AND REF(J,1)>=U2L,HHV(REF(H,1),BARSLAST(J>=U2L
AND REF(J,1)< U2L)-1),REF(HHV(REF(H,1),BARSLAST(J>=U2L
AND REF(J,1)< U2L)-1),BARSLAST(J< U2L AND REF(J,1))));
RH4:=IF(H>RH1,L,REF(L,BARSLAST(H>RH1)));
RH42:=IF(H>RH1,J,REF(J,BARSLAST(H>RH1)));
RH5:IF(H>RH4 AND J< RH42 AND J< J24,H,REF(H,BARSLAST(H>RH4 AND J< RH42 AND J< J24))),COLORGREEN;
RL1:=IF(J>L2L AND REF(J,1)<=L2L,LLV(REF(L,1),BARSLAST(J<=L2L AND REF(J,1)>L2L)-1),REF(LLV(REF(L,1),BARSLAST(J<=L2LAND
REF(J,1)>L2L)-1),BARSLAST(J>L2L AND REF(J,1))));
RL4:=IF(L< RL1,H,REF(H,BARSLAST(L< RL1)));
RL42:=IF(L< RL1,J,REF(J,BARSLAST(L< RL1)));
RL5:IF(L< RL4 AND J>RL42 AND J>J24,L,REF(L,BARSLAST(L< RL4 AND J>RL42 AND J>J24))),COLORMAGENTA;
CB:=AMOUNT/V/100;
CD:=CB>H OR CB< L;
STICKLINE(CD<1,CB-0.002,CB+0.002,8,1),COLORYELLOW;
小天导航:MA(C,3);
◆
小天K-KDJ指标的应用法则。该指标具有以下5项主要功能：
1.逃顶--(小天指标名:空中拦截)。
由于本指标采用的设计原理是：在主图上及时反映指标的顶背离逃顶，底背离抄底的技术手段。也就是说，如果能准确的理解这个指标，可以在瞬息万变的市场中，迅速的判断顶底。
（1）RH5的拦截：相当于顶部预警，通常的原则是，只要获利，出现RH5的拦截动作就应该出局。避免高位被套或是空利（已经获利，但没有挣到钱）。
（2）压力位的拦截：说明趋势已经逆转。
这两条线的向上抬头，可以形象的比喻为象导弹在空中击落飞机一样，一旦飞机被击中，开动会坠落的。这个指标中的RH5和压力线的主要作用是逃顶。
2.抄底--(小天指标名:海底金针，双剑合臂)。
RL5和支撑线的主要作用是用来抄底的。当股价向下运行时，首先这两条线对股价构成支撑，一旦这两条线被跌破，那么什么时间才能见底呢？这有两种情况：弱势之底；强势之底。
（1）弱势之底--海底金针。股价向下运行时，一些传统的技术分析指标会造成低位钝化，让人很难判断传统指标在低位置的金叉是不是可以买入？这个指标的优点是，不出现RL5或支撑线的向下打击就不可能出现底。
（2）强势之底--双剑合臂。股价的回调，有时不容易分清是洗盘还是向下破位。既很难区别是强势洗盘（主力没有出货），和出货后的下跌。传统的出货方式是拉高放量，但很多朋友不知道向下破位方式的出货。如果能搞清楚是洗盘，那么就可以低吸，买便宜货。其技术特征，股价回调时，受到支撑线的支撑，RL5从下向上迎接，并且，压力线和RL5合到一起，双剑和臂。这时形成的底部是强势洗盘结束，可在这时买入。这种强底往往是大行情的开始。
3.股票箱--(小天指标名:天地之间)。
这一功能具有预测意义。经常碰到这样的问题，反弹开始了，一但开始发动，能看到什么价位？或者，调整开始，能在什么地方准备抄底？反弹方法：当股价上穿支撑线和[RL5时，这时看一下压力线和RH5在什么位置，反弹的最终高度就在这个地方。
向下破位，先看一下前期的RL5在什么位置，这个数据告诉我们至少要有从破位点到此位置的落差，此时采取的策略是放空。底部的确认要采用前面讲过的底部技巧。
4.放空--(小天指标名:走为上计)。
放空，先走为上，探底预测，下跌的深度是可以预测的。
5.突破--(小天指标名:平地惊雷)。
发现黑马要领是，股价必须放量突破压力线。这种股票必须是，潜伏底或发生在(波浪理论)第3浪，第5浪；必须有双剑合臂的底部出现，因为，只有强势股票才能出现大行情；发力点位置的换手率通常在7%以上。
6.重要的补充内容，箱体内的行情结束点。
当股票价格在箱体内运行时，什么时间结束行情是一个非常重要的问题。这时，最容易与洗盘混为一谈，究竟是洗盘，还是行情结束呢？只要RH5线和压力线在股价相对高位闭合，就可以下一个结论，时间不允许行情发展了，到此结束，要有行情需要等待下一次机会。这个信号反映非常灵敏，一根阴线就可以决定行情的结束。它能保证你迅速出局。