高温蒸煮袋价格:Excel中Countif（）函数运用技巧

来源：百度文库 编辑：偶看新闻 时间：2024/04/28 07:30:48

Excel中Countif（）函数运用技巧

        Excel中能熟练地掌握函数的技巧，在水文日常工作中能达到事半功倍的效果。例如：要计算A1:An(定义：data)区域中非零的单元格的平均值，可在单元格中输入=sum(data)/countif(data, "<>0")。下面具体介绍Countif()函数的高级技巧如下：

一、求各种类型单元格的个数

所求类型单元格

 

 

公式

说明

真空单元格

=COUNTIF(data1,"=")

真空+假空单元格

=COUNTIF(data1,"")

相当于countblank()函数

非真空单元格

=COUNTIF(data1,"<>")

相当于counta()函数

文本型单元格

=COUNTIF(data1,"*")

假空单元格也是文本型单元格

区域内所有单元格

=COUNTIF(data1,"<>""")

数字型单元格

=COUNT(data1)

不是countif()，这里顺便点一下。

备注：data1为用户定义单元格区域，如用户把a1:d50区域定义为data1，以下data2、data3、data4、data5类同data1，也为用户定义的单元格区域。

 

二、求大于或小于等于某个值的单元格个数

大于50

 

 

=COUNTIF(data2,">50")

等于50

=COUNTIF(data2,50)

小于50

=COUNTIF(data2,"<50")

大于或等于50

=COUNTIF(data2,">=50")

小于或等于50

=COUNTIF(data2,"<=50")

大于E21单元格的值

=COUNTIF(data2,">"&$E$21)

等于E21单元格的值

=COUNTIF(data2,$E$21)

小于E21单元格的值

=COUNTIF(data2,"<"&$E$21)

大于或等于E21单元格的值

=COUNTIF(data2,">="&$E$21)

小于或等于E21单元格的值

=COUNTIF(data2,"<="&$E$21)

 

三、求等于或包含某N个特定字符的单元格个数

两个字符

 

 

=COUNTIF(data3,"??")

两个字符并且第2个是B

=COUNTIF(data3,"?B")

包含B

=COUNTIF(data3,"*B*")

第2个字符是B

=COUNTIF(data3,"?B*")

等于“你好”

=COUNTIF(data3,"你好")

包含D38单元格的内容

=COUNTIF(data3,"*"&D38&"*")

第2字是D38单元格的内容

=COUNTIF(data3,"?"&D38&"*")

备注：countif()函数对英文字母不区分大小写

 

四、不连续区域求个数

三个区域中>=60

 

 

=SUM(COUNTIF(INDIRECT({"a1:a10","b2:b20","c3:c30"}),">=60"))

三个区域中=70

=SUM(COUNTIF(INDIRECT({"a1:a10","b2:b20","c3:c30"}),70))

三个区域中<60

=SUM(COUNTIF(INDIRECT({"a1:a10","b2:b20","c3:c30"}),"<60"))

 

五、两个条件求个数

>10并且<=15

 

 

=SUM(COUNTIF(data4,">"&{10,15})*{1,-1})

>=10并且<15

=SUM(COUNTIF(data4,">="&{10,15})*{1,-1})

>=10并且<=15

=SUM(COUNTIF(data4,{">=10",">15"})*{1,-1})

>10并且<15

=SUM(COUNTIF(data4,{">10",">=15"})*{1,-1})

>10并且<=15

=COUNTIF(data4,">10")-COUNTIF(data4,">15")

 

六、数据的有效性验证

  首先，选择要设置有效性验证区域（如：A1:A100，定义为：data5）中的任一单元格(假设为：A1)，在excel工作表中，用鼠标依次点击菜单栏数据→有效性菜单命令，打开“数据有效性”对话框，在“允许”下拉按钮中设置有效性条件为“自定义”，在“公式”框中输入 =COUNTIF(data5,A1)<2，然后，复制A1单元格,选中除A1外的所有单元格（A2:A100），用鼠标依次点击编辑→选择性粘贴命令→粘贴→有效性验证。这样即实现了数据data5区域中不重复的验证条件。

请问Excel中dcount和countif两函数的区别？ 关于excel的countif函数 关于excel的countif函数 EXCEL的COUNTIF这个函数中,60-69这个条件要怎么输入啊? excel- 函数countif若有2个条件怎么办? excel中函数表达式中的不等号后面除了直接跟数字外，还可以引用其它单元格的数据吗？比如说countif函数。 关于EXCEL函数的运用 关于EXCEL函数的运用 Excel里的函数CountIf与函数Counta有什么不同啊？ 如何运用EXCEL中的引用函数? 谁能帮我例出Excel中：宏，函数，数据透视表的运用程序 EXCEL表中函数 这个公式在Excel中如何运用函数计算．=[1－（∣报价－最低价∣）÷最低价]×30 Excle中countif函数，如何同时定义两列相隔的单元格作为计算区域 为什么函数“countif”不能算出字符的数目，要算单元格中字符的数目该用什么函数？？ 在excel里如何运用函数"rank"? 在office excel 里能用运用函数求积吗 谁有学习 Excel 里函数运用的教程 如何写Excle中的countif函数 countif函数或编程解答此问题 Excel里的函数CountIf可以限定多个条件吗？如果我要对数据取几位小数，应该用什么函数？ Excel 函数中RC是什么意思 EXCEL中怎么使用函数？ EXCEL 中IF函数问题!