广州标美硅氟有限公司:44b0引导注释(一)

*******************************************************
; * NAME : 44BINIT.S *
; * Version : 10.JAn.2003 *
; * Description: *
; * C start up codes *
; * Configure memory, Initialize ISR ,stacks *
; * Initialize C-variables *
; * Fill zeros into zero-initialized C-variables *
; *******************************************************
GET option.s ;相当于c语言中的＃include "option.s"
GET memcfg.s
;Interrupt Control
;声明一些符号常量，这些符号常量和地址相应寄存器的地址对应
INTPND EQU 0x01e00004 ;指示中断请求状态寄存器 每一位代变一种中断请求具体表一种中断请参考44b0 spec
INTMOD EQU 0x01e00008 ;中断模式寄存器 有两种中断模式对应位为1代表fip mode 0代表riq mode
INTMSK EQU 0x01e0000c ;确定哪个中断源被屏蔽屏蔽的中断源将不被服务
I_ISPR EQU 0x01e00020 ;中断服务挂起寄存器
I_CMST EQU 0x01e0001c ;当前主寄存器irq优先级
;Watchdog timer
WTCON EQU 0x01d30000 ;看门狗定时器控制寄存器
;Clock Controller
PLLCON EQU 0x01d80000 ;pll控制寄存器
CLKCON EQU 0x01d80004 ;时钟控制寄存器
LOCKTIME EQU 0x01d8000c ;锁定时间计数值寄存器
;Memory Controller
REFRESH EQU 0x01c80024 ;Dram/sdram刷新控制寄存器
;下面是对arm处理器模式寄存器对应值的常数定义，arm处理器中有一个CPSR程序状态寄存器它的后五位决定目前的处理器模式
;Pre-defined constants
USERMODE EQU 0x10 ;CPSR后5位为10000设定为用户模式
FIQMODE EQU 0x11 ;10001FIQ模式
IRQMODE EQU 0x12 ;10010IRQ模式
SVCMODE EQU 0x13 ;10011管理模式
ABORTMODE EQU 0x17 ;10111中止模式
UNDEFMODE EQU 0x1b ;11011未定义
MODEMASK EQU 0x1f ;11111系统模式
NOINT EQU 0xc0 ;
;check if tasm.exe is used.
;arm处理器有两种工作状态 1.arm:32位 这种工作状态下执行字对准的arm指令 2.Thumb:16位这种工作状态执行半字对准的Thumb指令
;因为处理器分为16位 32位两种工作状态程序的编译器也是分16位和32两种编译方式所以下面的程序用于根据处理器工作状态确定编译器编译方式
;code16伪指令指示汇编编译器后面的指令为16位的thumb指令
;code32伪指令指示汇编编译器后面的指令为32位的arm指令
;这段是为了统一目前的处理器工作状态和编译方式（16位编译环境使用tasm.exe译）
;其中[=IF ，|=ELSE ，]= ENDIF， CODE32 表明一下操作都在ARM状态。这些都是伪操作
;这段我理解为设定THUMCODE的值，然后确定，用户的程序是在ARM状态还是THUM状态。不过不管THUMCODE
;何值下面代码都是ARM状态
GBLL THUMBCODE ;设置一个全局变量
[ {CONFIG} = 16 ;if config==16 这里表示你的目前处于领先地16位编译方式
THUMBCODE SETL {TRUE} ;设置THUMBCODE 为 true
CODE32 ;转入32位编译模式
|  ;else
THUMBCODE SETL {FALSE} ;设置THUMBCODE 为 false
]
[ THUMBCODE ;if THUMBCODE==TRUE
CODE32 ;for start-up code for Thumb mode;转入32位编译方式
]
;注意下面这段程序是个宏定义很多人对这段程序不理解我再次强调这是一个宏定义所以大家要注意了下含的HandlerXXX HANDLER HandleXXX将都被下面这段程序展开
;这段程序用于把中断服务程序的首地址装载到pc中，有人称之为“加载程序”。
;本初始化程序定义了一个数据区（在文件最后），34个字空间，存放相应中断服务程序的首地址。每个字空间都有一个标号，以Handle***命名。
;在向量中断模式下使用“加载程序”来执行中断服务程序。
;这里就必须讲一下向量中断模式和非向量中断模式的概念
;向量中断模式是当cpu读取位于0x18处的IRQ中断指令的时候，系统自动读取对应于该中断源确定地址上的指令取代0x18处的指令，通过跳转指令系统就直接跳转到对应地址
;函数中 节省了中断处理时间提高了中断处理速度标 例如 ADC中断的向量地址为0xC0,则在0xC0处放如下代码：ldr PC,=HandlerADC 当ADC中断产生的时候系统会
;自动跳转到HandlerADC函数中
;非向量中断模式处理方式是一种传统的中断处理方法，当系统产生中断的时候，系统将interrupt pending寄存器中对应标志位置位然后跳转到位于0x18处的统一中断
;函数中 该函数通过读取interrupt pending寄存器中对应标志位来判断中断源并根据优先级关系再跳到对应中断源的处理代码中
MACRO
＄HandlerLabel HANDLER ＄HandleLabel
＄HandlerLabel
sub sp,sp,#4 ;decrement sp(to store jump address)
stmfd sp!,{r0} ;PUSH the work register to stack
;将要使用的r0寄存器入栈
ldr r0,=＄HandleLabel;load the address of HandleXXX to r0
ldr r0,[r0] ;
str r0,[sp,#4] ;store the contents(ISR) of HandleXXX to stack
;将对应的中断函数首地址入栈
ldmfd sp!,{r0,pc} ;POP the work register and pc(jump to ISR)
;将中断函数首地址出栈 放入程序指针中 系统将跳转到对应中断处理函数
MEND
;一个arm由RO,RW,ZI三个断组成其中RO为代码段，RW是已经初始化的全局变量，ZI是未初始化的全局变量（对于GNU工具对应的概念是TEXT ,DATA,BSS）bootloader
;bootloader要将RW段复制到ram中并将ZI段清零 编译器使用下列段来记录各段的起始和结束地址
; |Image＄＄RO＄＄Base| ; RO段起始地址
; |Image＄＄RO＄＄Limit| ; RO段结束地址加1
; |Image＄＄RW＄＄Base| ; RW段起始地址
; |Image＄＄RW＄＄Limit| ; RW段结束地址加1
; |Image＄＄ZI＄＄Base| ; ZI段起始地址
; |Image＄＄ZI＄＄Limit| ; ZI段结束地址加1
;这些标号的值是通过编译器的设定来确定的如编译软件中对ro-base和rw-base的设定，例如 ro-base=0xc000000 rw-base=0xc5f0000
IMPORT |Image＄＄RO＄＄Limit| ; End of ROM code (=start of ROM data)
IMPORT |Image＄＄RW＄＄Base| ; Base of RAM to initialise
IMPORT |Image＄＄ZI＄＄Base| ; Base and limit of area
IMPORT |Image＄＄ZI＄＄Limit| ; to zero initialise
IMPORT Main ; The main entry of mon program
;下面为代码段
AREA Init,CODE,READONLY
;异常中断矢量表（每个表项占4个字节）下面是中断向量表一旦系统运行时有中断发生即使移植了操作系统 如linux 处理器已经把控制权交给了操作系统一旦发生中断处理器还是会跳转到从0x0开始
;中断向量表中某个中断表项（依据中断类型）开始执行
;具体中断向量布局请参考s3c44b0 spec 例如 adc中断向量为 0x000000c0下面对应表中第49项位置向量地址0x0+4*(49-1)=0x000000c0
ENTRY
;扳子上电和复位后 程序开始从位于0x0处开始执行刚刚上电复位后程序从这里开始执行跳转到标号为ResetHandler处执行
;与FLASH上地址一一对应
b ResetHandler ;for debug 0x00000000
b HandlerUndef ;handlerUndef 0x00000004
b HandlerSWI ;SWI interrupt handler 0x00000008
b HandlerPabort ;handlerPAbort 0x0000000c
b HandlerDabort ;handlerDAbort 0x00000010
b . ;handlerReserved 0x00000014
b HandlerIRQ ;0x00000018
b HandlerFIQ
;***IMPORTANT NOTE***
;If the H/W vectored interrutp mode is enabled, The above two instructions should
;be changed like below, to work-around with H/W bug of S3C44B0X interrupt controler.
; b HandlerIRQ -> subs pc,lr,#4
; b HandlerIRQ -> subs pc,lr,#4
VECTOR_BRANCH ;与FLASH上地址一一对应
ldr pc,=HandlerEINT0 ;mGA H/W interrupt vector table
ldr pc,=HandlerEINT1 ;
ldr pc,=HandlerEINT2 ;
ldr pc,=HandlerEINT3 ;
ldr pc,=HandlerEINT4567 ;
ldr pc,=HandlerTICK ;mGA
b .
b .
ldr pc,=HandlerZDMA0 ;mGB
ldr pc,=HandlerZDMA1 ;
ldr pc,=HandlerBDMA0 ;
ldr pc,=HandlerBDMA1 ;
ldr pc,=HandlerWDT ;
ldr pc,=HandlerUERR01 ;mGB
b .
b .
ldr pc,=HandlerTIMER0 ;mGC
ldr pc,=HandlerTIMER1 ;
ldr pc,=HandlerTIMER2 ;
ldr pc,=HandlerTIMER3 ;
ldr pc,=HandlerTIMER4 ;
ldr pc,=HandlerTIMER5 ;mGC
b .
b .
ldr pc,=HandlerURXD0 ;mGD
ldr pc,=HandlerURXD1 ;
ldr pc,=HandlerIIC ;
ldr pc,=HandlerSIO ;
ldr pc,=HandlerUTXD0 ;
ldr pc,=HandlerUTXD1 ;mGD
b .
b .
ldr pc,=HandlerRTC ;mGKA
b . ;
b . ;
b . ;
b . ;
b . ;mGKA
b .
b .
ldr pc,=HandlerADC ;mGKB
b . ;
b . ;
b . ;
b . ;
b . ;mGKB
b .
b .
;0xe0=EnterPWDN
ldr pc,=EnterPWDN
LTORG
;下面是具体的中断处理函数跳转的宏，通过上面的＄HandlerLabel的宏定义展开后跳转到对应的中断处理函数（对于向量中断）
HandlerFIQ HANDLER HandleFIQ
HandlerIRQ HANDLER HandleIRQ
HandlerUndef HANDLER HandleUndef
HandlerSWI HANDLER HandleSWI
HandlerDabort HANDLER HandleDabort
HandlerPabort HANDLER HandlePabort
HandlerADC HANDLER HandleADC
HandlerRTC HANDLER HandleRTC
HandlerUTXD1 HANDLER HandleUTXD1
HandlerUTXD0 HANDLER HandleUTXD0
HandlerSIO HANDLER HandleSIO
HandlerIIC HANDLER HandleIIC
HandlerURXD1 HANDLER HandleURXD1
HandlerURXD0 HANDLER HandleURXD0
HandlerTIMER5 HANDLER HandleTIMER5
HandlerTIMER4 HANDLER HandleTIMER4
HandlerTIMER3 HANDLER HandleTIMER3
HandlerTIMER2 HANDLER HandleTIMER2
HandlerTIMER1 HANDLER HandleTIMER1
HandlerTIMER0 HANDLER HandleTIMER0
HandlerUERR01 HANDLER HandleUERR01
HandlerWDT HANDLER HandleWDT
HandlerBDMA1 HANDLER HandleBDMA1
HandlerBDMA0 HANDLER HandleBDMA0
HandlerZDMA1 HANDLER HandleZDMA1
HandlerZDMA0 HANDLER HandleZDMA0
HandlerTICK HANDLER HandleTICK
HandlerEINT4567 HANDLER HandleEINT4567
HandlerEINT3 HANDLER HandleEINT3
HandlerEINT2 HANDLER HandleEINT2
HandlerEINT1 HANDLER HandleEINT1
HandlerEINT0 HANDLER HandleEINT0
;One of the following two routines can be used for non-vectored interrupt.
;这段是没有使用非向量模式下如何装载中断子程序,因为44B0有30个中断源,所以需要程序处理以确定调用那个中断程序
;0,1是局部标号,％B是向后搜索局部标号, %F是向前搜索局部标号 。都是伪操作
;I_ISPR寄存器各位表明发生了应该调用那个中断子程序。只能1位置位,其它位为0,比如说串口1发送中断发生,这时I_ISPR的
;值为0X04,ldr r9,=I_ISPR
;ldr r9,[r9] 两条指令后,r9的内容为0X4 ,
;movs r9,r9,lsr #1 r9内容右移一位
;bcs %F1 判断是否把置位是否转移到C位,
;add r8,r8,#4 如果没有的R8加4
;如果r9内容为0x04 需要右移3次 ,之后r8的内容为8 然后HandleADC的地址加上r8的值就是串口1发送中断的地址,这个地址的内容是中断子程序的地址
IsrIRQ ;using I_ISPR register.
sub sp,sp,#4 ;reserved for PC 预留给PC，以便下面的程序中把中断函数入口放入此位置，出栈给PC
stmfd sp!,{r8-r9}
;IMPORTANT CAUTION
;if I_ISPC isn't used properly, I_ISPR can be 0 in this routine.
ldr r9,=I_ISPR
ldr r9,[r9]
mov r8,#0x0
0
movs r9,r9,lsr #1
bcs %F1 ;检测I_ISPR哪位被置1  %F1表示向前跳转到1标识
add r8,r8,#4
b %B0   ；向后跳转到标号1
； 这段构成一个循环检测I_ISPR哪位被置一并计算出中断入口地址的偏移量
1
ldr r9,=HandleADC
add r9,r9,r8 ;计算出中断函数入口地址
ldr r9,[r9]
str r9,[sp,#8] ;将中断函数入口地址放入预留堆栈
ldmfd sp!,{r8-r9,pc} ;将中断入口函数地址出栈给PC