黎明契约之狼族后裔2:如何将心爱的指标变成选股公式

如何将心爱的指标变成选股公式

我们常常会得到一些比较好的公式，这些公式在某些个股上相当的好用。但有时我们发现它时，已经失去了最好的介入时机。
如何提前关注了，当然最好提前发现。或者用自己常用的一两个指标进行交叉选股，甚至进行合并选股。那么，前提是要将它们改写成选股公式。我们将以下面中的两个指标为例，教大家改写指标。最好有点编程知识，

首先，必须先得到指标源码。一般通过以下路径， 功能>专家系统>公式管理器>，然后查找、点选。再点击右边的修改。
   复制、备份指标源码。

一、下面是波段介入点的指标源码：

顶:80,COLORFFA500;
大顶:100,COLORBLUE;
VAR1:=(CLOSE-LLV(LOW,60))/(HHV(HIGH,60)-LLV(LOW,60))*80;
VAR2:=SMA(VAR1,10,1);
慢速:SMA(VAR2,5,1),COLORRED;
RSV:= ((HHV(HIGH,9)-CLOSE)/(HHV(HIGH,9)-LLV(LOW,9))*100)-70;
RSV1:= (CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
FATK:=SMA(RSV1,3,1);
形态:SMA(FATK,3,1),COLORBB24DB;
VARA:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
VARB:=SMA(VARA,3,1);
VARC:=SMA(VARB,3,1);
加速: EMA(3*VARB-2*VARC,3),COLORYELLOW;
底:6,COLOR00BF00;
大底:-6,COLOR007300;
VAR11:=LLV(LOW,5)=LLV(LOW,45) AND CLOSE>=OPEN*1.04;
VAR22:=CLOSE>(REF(HIGH,1)+REF(LOW,1))/2;
买入:=VAR11 AND VAR22,STICK,LINETHICK2,COLORRED;
VAR3:=REF(CLOSE,1);
VAR4:=SMA(MAX(CLOSE-VAR3,0),6,1)/SMA(ABS(CLOSE-VAR3),6,1)*100;
卖出:=CROSS(80,VAR4),STICK,LINETHICK2,COLORGREEN;
{波段介入点}
A1:=REF(CLOSE,2);
A2:=SMA(MAX(CLOSE-A1,0),7,1)/SMA(ABS(CLOSE-A1),7,1)*100;
波段介入点:IF(A2<19,19,0)COLORWHITE;

复制一份该指标源码，按路径， 功能>专家系统>公式管理器>，在该目录下点选 用户>条件选股公式>指标条件选股 。保持选中状态，点选右边的 新建 按钮。将复制的源码粘贴到窗口上。

开始修改；
1，在公式名称中输入一个自己喜欢的名称。如：波段选股。
2，将字符改成字母。“顶”改为“DING”；“大顶”改为“DDING”。
3，将输出语句全部改为赋值语句。即将“：”后没有“=”这个符号的全部加上。如：“顶:80,COLORFFA500;”改后为：“DING:=80,COLORFFA500;”。同时，注意动态翻译中的变化。
4，将需要画图、画色、画线的语句全部删除。如：

“顶:80,COLORFFA500;”改后为：“DING:=80;”
“慢速:SMA(VAR2,5,1),COLORRED;”改后为：“MANSU:=SMA(VAR2,5,1);”

同时，注意动态翻译中的变化。

5，最后，加入选股的条件。如：慢速线小于多少，加速线小于多少。条件可以多个，中间用AND、OR连接。
这里我们选择慢速线小于25，加速线介于于50——100间。语句为：
MANSU<25 AND JIASU>50 AND JIASU<100 ;

6,点选 测试公式 按钮，看是否正确。

最终改写后的公式为：


DING:=80;
DDING:=100;
VAR1:=(CLOSE-LLV(LOW,60))/(HHV(HIGH,60)-LLV(LOW,60))*80;
VAR2:=SMA(VAR1,10,1);
MANSU:=SMA(VAR2,5,1);
RSV:= ((HHV(HIGH,9)-CLOSE)/(HHV(HIGH,9)-LLV(LOW,9))*100)-70;
RSV1:= (CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
FATK:=SMA(RSV1,3,1);
XITAI:=SMA(FATK,3,1);
VARA:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
VARB:=SMA(VARA,3,1);
VARC:=SMA(VARB,3,1);
JIASU:= EMA(3*VARB-2*VARC,3);
DI:=6;
DDI:=-6;
VAR11:=LLV(LOW,5)=LLV(LOW,45) AND CLOSE>=OPEN*1.04;
VAR22:=CLOSE>(REF(HIGH,1)+REF(LOW,1))/2;
MAIRU:=VAR11 AND VAR22;
VAR3:=REF(CLOSE,1);
VAR4:=SMA(MAX(CLOSE-VAR3,0),6,1)/SMA(ABS(CLOSE-VAR3),6,1)*100;
MAICHU:=CROSS(80,VAR4);
{波段介入点}
A1:=REF(CLOSE,2);
A2:=SMA(MAX(CLOSE-A1,0),7,1)/SMA(ABS(CLOSE-A1),7,1)*100;
波段介入点:=IF(A2<19,19,0);

MANSU<25 AND JIASU>50 AND JIASU<100;

二、改写愚公涨跌指标。

源码：

Q2:=(CLOSE-LLV(LOW, 18))/(HHV(HIGH, 18)-LLV(LOW, 18))*100;
Q3:=SMA(Q2, 9, 1);
Q4:=SMA(Q3, 3, 1);
长趋势:3*Q3-2*Q4,COLORWHITE,LINETHICK3;
趋势线:EMA(Q3, 3),COLORRED,LINETHICK3;
DRAWTEXT(CROSS(趋势线, 长趋势) AND REF(长趋势,1)>80, REF(长趋势,3), '顶'),COLORRED,LINETHICK5;
逢低买: DRAWTEXT(REF(CROSS(趋势线,长趋势),82) AND 趋势线>1.3*长趋势,长趋势,'逢低买'),LINETHICK1;
买: DRAWTEXT(REF(CROSS(长趋势,趋势线),1) AND 长趋势>1.3*趋势线,趋势线,'买'),COLORRED,LINETHICK1;
VAR3:=PEAKBARS(3,15,1)<10;
VAR5:=IF(VAR3=1,2,0);
顶:= IF(VAR5=2,2,0);
顶A:IF(顶>REF(顶,1),50,0),COLORGREEN;
DRAWTEXT(顶A=50,45,'快逃'),COLOR00FF00;
金叉: CROSS(长趋势,趋势线);
DRAWTEXT(金叉,趋势线,'★'),COLORRED;

修改后为：



Q2:=(CLOSE-LLV(LOW, 18))/(HHV(HIGH, 18)-LLV(LOW, 18))*100;
Q3:=SMA(Q2, 9, 1);
Q4:=SMA(Q3, 3, 1);
长趋势:=3*Q3-2*Q4;
趋势线:=EMA(Q3, 3);
逢低买:=REF(CROSS(趋势线,长趋势),82) AND 趋势线>1.3*长趋势;
买:= REF(CROSS(长趋势,趋势线),1) AND 长趋势>1.3*趋势线;
VAR3:=PEAKBARS(3,15,1)<10;
VAR5:=IF(VAR3=1,2,0);
顶:= IF(VAR5=2,2,0);
JIN:=IF( CROSS(长趋势,趋势线)>0,1,0);
JIN>0;

在这一指标中，我们去掉DRAWTEXT函数，以及加入自己所需要的选股条件JIN>0，为了符合我们的条件，我们将
“金叉: CROSS(长趋势,趋势线);”改为：“JIN:=IF( CROSS(长趋势,趋势线)>0,1,0);”
意思是如果金叉成立，把“1”赋给“JIN\"这时“JIN=1”；
金叉不成立的话，把“０”赋给“JIN\"这时“JIN=０”；

在上面的选股公式中还可以加入基本面的选股条件，中间用AND。

DYNAINFO(39)>0 AND DYNAINFO(39)<=N;   市盈率在n之间
FINANCE(33)>0 AND FINANCE(33)<=N;   每股收益在n之间
FINANCE(34)>0 AND FINANCE(34)<=N;   每股净资产在n之间
FINANCE(7)>0 AND FINANCE(7)<=N;   流通盘大小n之间（单位：万股）

如：JIN>0 AND DYNAINFO(39)>0 AND DYNAINFO(39)<=50;