ANSYS动力学分析的几个入门例子

.threadtags_tag {margin:0px !important;background:none !important;padding:12px 0 !important;color: #444 !important;}.threadtags_tag span {border:1px solid #E6E7E1; padding:10px 14px 10px 32px; background: url(http://images.5d6d.net/dz7/default/tag.gif) no-repeat 10px 50%;}.threadtags_tag a{color:#09C !important;}相关搜索: ANSYS, 动力学分析, 入门, 例子 转自 http://laplace0008.blog.163.com
三角平台受一地震谱激励,求应力分布和支反力

基本过程：
1、建模
2、求模态解
3、求谱解
4、扩展模态
5、模态合并
6、观察结果

/PREP7 !建模
ET,1,BEAM189
ET,2,SHELL93
R,1,0.01, , , , , ,
MP,EX,1,210e9
MP,PRXY,1,0.3
MP,DENS,1,7850
SECTYPE, 1, BEAM, RECT, secA, 0
SECOFFSET, CENT
SECDATA,0.005,0.008,0,0,0,0,0,0,0,0

K, ,-0.5,,,
K, ,0.5,,,
K, ,,,1,
K, ,,1,1,
K, ,-0.5,1,,
K, ,0.5,1,,
K, ,,,0.5,
A,4,5,6
LSTR, 1, 5
LSTR, 3, 4
LSTR, 2, 6
LSEL,S,LINE,,4,6
LATT,1,1,1, , 7, ,1
LSEL, , , ,ALL
LESIZE,ALL, , ,10, , , , ,1
LMESH,4,6
TYPE, 2
MSHAPE,0,2D
MSHKEY,1
AMESH,1
FINISH

/SOL !取前十阶模态
ANTYPE,2
MODOPT,LANB,10
KSEL,S,KP,,1,3
DK,ALL, , , ,0,ALL, , , , , ,
SOLVE
FINISH

/SOL !谱分析
ANTYPE,8
SPOPT,SPRS,10,1
SVTYP,3
SED,0,1,0, !给出激励方向
FREQ,0.25,1.34,6.73,14.6,28.9,0,0,0,0 !激励谱
SV,0,0.00073,0.00016,0.00034,0.00034,0.00052,
SOLVE
FINISH

/SOL !扩展模态
ANTYPE,2
EXPASS,1
MXPAND,10,0,0,1,0.001,
SOLVE
FINISH

/SOL !模态合并
ANTYPE,8
SRSS,0.001,DISP
SOLVE

/POST1 !观察结果
SET,LIST
/INPUT,,mcom
PRRSOL,F
FINISH








问题三：三角平台受谐波载荷作用,求结构响应
谐波载荷为作用在平台上面一点的集中力，幅值为10N，频率范围5Hz~70Hz

基本过程：
1、建模
2. 求模态解
3、用模态叠加法作谐分析
4. 观察结果

/PREP7 !建模
ET,1,BEAM189
ET,2,SHELL93
R,1,0.01, , , , , ,
MP,EX,1,210e9
MP,PRXY,1,0.3
MP,DENS,1,7850
SECTYPE, 1, BEAM, RECT, secA, 0
SECOFFSET, CENT
SECDATA,0.005,0.008,0,0,0,0,0,0,0,0
K, ,-0.5,,,
K, ,0.5,,,
K, ,,,1,
K, ,,1,1,
K, ,-0.5,1,,
K, ,0.5,1,,
K, ,,,0.5,
A,4,5,6
LSTR, 1, 5
LSTR, 3, 4
LSTR, 2, 6
LSEL,S,LINE,,4,6
LATT,1,1,1, , 7, ,1
LSEL, , , ,ALL
LESIZE,ALL, , ,10, , , , ,1
LMESH,4,6
TYPE, 2
MSHAPE,0,2D
MSHKEY,1
AMESH,1
FINISH

/SOL !为了使用模态叠加法谐分析
ANTYPE,2
MODOPT,LANB,20 !先取结构前20阶模态
MXPAND,20, , ,0
MODOPT,LANB,20,0,0, ,OFF
KSEL,S,KP,,1,3
DK,ALL, , , ,0,ALL, , , , , ,
SOLVE
FINISH

!/POST1 !最好事先看一下模态结果
!SET,LIST !以了解模态频率范围
!FINISH

/SOL !模态叠加法谐响应分析
ANTYPE,3
HROPT,MSUP
HROUT,ON
HROPT,MSUP,20, ,
HROUT,ON,OFF,0
F,177,FY,-10, !施加10N的力在节点177的负Y方向
HARFRQ,5,70, !载荷的强制频率范围
NSUBST,200,
KBC,1
ALPHAD,5,
SOLVE
FINISH

/POST26 !察看位移响应
FILE,,rfrq
NUMVAR,20
NSOL,2,139,U,Y,
PLVAR,2
FINISH





循环对称结构模态分析
这是ANSYS HELP里的例子，但那个命令流似乎有些问题，下面是整理过的命令流。

基本过程：
1、建模
2、define cyclic
3、定义约束
4、求模态解
5、展开并察看结果

r1=5 !建模
r2=10
d1=2
nsect=24
alpha_deg=360/nsect
alpha_rad=2*acos(-1)/nsect

/prep7
csys,1
k,1,0,0,0
k,2,0,0,d1
k,3,r1,0,0
k,4,r1,0,d1
l,3,4
arotat,1,,,,,,1,2,alpha_deg/2
k,7,r2,0,0
k,8,r2,0,d1
l,7,8
arotat,5,,,,,,1,2,alpha_deg/2
arotat,2,,,,,,1,2,alpha_deg/2
arotat,6,,,,,,1,2,alpha_deg/2
a,5,6,10,9
mshkey,1
et,1,181
r,1,0.20
r,2,0.1
mp,ex,1,10e6
mp,prxy,1,0.3
mp,dens,1,1e-4
esize,0.5
asel,,,,1,4
aatt,,1
asel,,,,5
aatt,,2
allsel

CYCLIC, , , ,'CYCLIC' !定义基本扇区
AMESH,all !分网
FINISH

/SOL !求模态解
ANTYPE,2
MODOPT,LANB,10
MXPAND,10, , ,0
PSTRES,0
MODOPT,LANB,10,0,0, ,OFF
DK,5, , , ,0,UZ, , , , , ,
SOLVE
FINISH

/POST1
SET,LIST
SET, , ,1, , , ,4,
/CYCEXPAND, ,ON
PLNS,U,SUM !观察扩展模态
FINISH